;ledgp2s-NMR-School Mexico
;adaptable a plataformas Bruker AV II, III y AV Neo
;Previamente, calibrar tiempo de difusion (d20, BIG-DELTA) y amplitud de gradiente (p30, LITTLE-DELTA)
; con valores especificos de amplitud de gradiente (2% / 98%) sobre el experimento 1D (ledbpgp2s1d)
;Fijar d20 a 50ms (menor polidispersion) o 100ms (mayor polidispersion) y variar p30 (1-5 ms)
;
;Herbert-Pucheta, J.E., et al., 
;   Anal. Chem. 91:22, (2019),1439214400
;
;$CLASS=HighRes
;$DIM=2D
;$TYPE=
;$SUBTYPE=
;$COMMENT=


#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>


define list<gradient> diff=<Difframp>


"DELTA1=d20-p1*2-p30-d16-p19-d16"
"DELTA2=d21-p19-d16-4u"


"acqt0=-p1*2/3.1416"


1 ze
2 d1
3 50u UNBLKGRAD
  p1 ph1
  p30:gp6*diff
  d16
  p1 ph1
  p19:gp7
  d16
  DELTA1
  p1 ph1
  p30:gp6*diff
  d16
  p1 ph2
  p19:gp8
  d16
  DELTA2
  4u BLKGRAD
  p1 ph3
  go=2 ph31
  d1 mc #0 to 2 F1QF(calgrad(diff))
exit


ph1= 0 0 0 0 0 0 0 0  2 2 2 2 2 2 2 2
     1 1 1 1 1 1 1 1  3 3 3 3 3 3 3 3
ph2= 0 0 0 0 2 2 2 2  2 2 2 2 0 0 0 0
     1 1 1 1 3 3 3 3  3 3 3 3 1 1 1 1
ph3= 0 1 2 3 2 3 0 1  2 3 0 1 0 1 2 3
     1 2 3 0 3 0 1 2  3 0 1 2 1 2 3 0
ph31=0 1 2 3 0 1 2 3  2 3 0 1 2 3 0 1
     1 2 3 0 1 2 3 0  3 0 1 2 3 0 1 2


;pl1 : f1 channel - power level for pulse (default)
;p1  : f1 channel -  high power pulse
;p19: gradient pulse 2 (spoil gradient)
;p30: gradient pulse (little DELTA)
;d1  : relaxation delay; 1-5 * T1
;d16: delay for gradient recovery
;d20: diffusion time (big DELTA)
;d21: eddy current delay (Te)			[5 ms]
;ns: 8 * n
;ds: 4 * m
;td1: number of experiments
;FnMODE: QF
;        use xf2 and DOSY processing


;use gradient ratio:    gp 6 : gp 7   : gp 8
;                       100  : -17.13 : -13.17

;for z-only gradients:
;gpz6: 100%
;gpz7: -17.13% (spoil)
;gpz8: -13.17% (spoil)

;use gradient files:   
;gpnam6: SMSQ10.100
;gpnam7: SMSQ10.100
;gpnam8: SMSQ10.100

;use AU-program dosy to calculate gradient ramp-file Difframp



;$Id: ledgp2s,v 1.8 2012/01/31 17:49:27 ber Exp $